
Features
	  ⚡ End-To-End Reactivity with LiveView
	  🔋 Server-Side Rendered (SSR) Svelte
	  🪄 Sigil as an Alternative LiveView DSL
	  ⭐ Svelte Preprocessing Support with svelte-preprocess
	  🦄 Tailwind Support
	  💀 Dead View Support
	  🦥 Slot Interoperability
	  📘 TypeScript — client assets in TypeScript; public API is type-safe with exported type definitions for consumers

Resources
	  HexDocs
	  HexPackage
	  Phoenix LiveView
	  Blog Post
	  YouTube Introduction

Demo
For a full intro and demo check out the YouTube introduction
/examples/advanced_chat
https://user-images.githubusercontent.com/3637265/229902870-29166253-3d18-4b24-bbca-83c4b6648578.webm

Svelte handles the look and feel of the chat, while LiveView takes care of syncing. E2E reactivity to the Svelte component so we don't really need to fetch anything! The 'login' to enter your name is a simple LiveView form. Hybrid!

/examples/breaking_news
https://user-images.githubusercontent.com/3637265/229902860-f7ada6b4-4a20-4105-9ee9-79c0cbad8d72.webm

News items are synced with the server while the speed is only client side.
Why LiveSvelte
Phoenix LiveView enables rich, real-time user experiences with server-rendered HTML.
It works by communicating any state changes through a websocket and updating the DOM in realtime.
You can get a really good user experience without ever needing to write any client side code.
LiveSvelte builds on top of Phoenix LiveView to allow for easy client side state management while still allowing for communication over the websocket.
Reasons why you'd use LiveSvelte
	  You have (complex) local state
	  You want to take full advantage of Javascript's ecosystem
	  You want to take advantage of Svelte's animations
	  You want scoped CSS
	  You like Svelte and its DX :)

Requirements
For Server-Side Rendering (SSR) to work you need node (version 19 or later) installed in your environment.
Make sure you have it installed in production too. You might be using node in the build step, but it might actually not be installed in your production environment.
You can make sure you have node installed by running node --version in your project directory.
You can also use Bun instead of Node.js/npm for installing dependencies and running Vite (see Installation); production SSR still uses Node.js.
If you don't want SSR, you can disable it by not setting NodeJS.Supervisor in application.ex. More on that in the SSR section of this document.
Installation
If you're updating from an older version, make sure to check the CHANGELOG.md for breaking changes.
LiveSvelte uses Vite for building and phoenix_vite to integrate it with Phoenix. The layout uses PhoenixVite.Components.assets; in development the endpoint runs a Vite watcher and points asset URLs at the Vite dev server so Svelte and CSS changes hot-reload with no extra terminal. The recommended way to install is via the Igniter installer, which configures phoenix_vite (including the dev watcher and static_url) and all LiveSvelte steps.
Option A — Igniter installer (recommended)
Requires Phoenix 1.8+ and Node.js 19+ (or Bun for package management and builds).
New project
mix archive.install hex igniter_new
mix igniter.new my_app --with phx.new --install live_svelte
cd my_app
mix setup
mix phx.server

Existing project
Igniter must be present in the project's deps before the installer can run.
	Add igniter to mix.exs:

defp deps do
  [
    # ... existing deps ...
    {:igniter, "~> 0.6"}
  ]
end
	Fetch and run the installer (this adds live_svelte, configures phoenix_vite, Vite, app.js, html_helpers, SSR, layout with PhoenixVite.Components.assets, and more):

mix deps.get
mix igniter.install live_svelte

	Install npm packages and build assets:

mix assets.setup     # phoenix_vite.npm assets install
mix assets.build     # Vite client + SSR builds (or run mix setup to do both)

	Start the server:

mix phx.server

With phoenix_vite, the layout uses PhoenixVite.Components.assets and the endpoint uses PhoenixVite.Plug; no separate Vite terminal is required for dev — phoenix_vite integrates the Vite dev server.
Visit http://localhost:4000/svelte_demo to confirm the demo Svelte component is working.
Using Bun
Use the --bun flag to use Bun instead of npm/npx:
	Existing project: mix igniter.install live_svelte --bun
	New project: mix igniter.new my_app --with phx.new --install live_svelte --bun


Option B — Manual installation
Use this if you prefer not to use Igniter, or need full control over the configuration.
These steps cover a fresh Phoenix 1.8 project (which uses esbuild by default). You will replace esbuild with Vite and add LiveSvelte on top.
To use Bun instead of npm, see the Installation guide for details.
1. Update mix.exs — remove :esbuild (and :tailwind if present), add live_svelte and phoenix_vite:
defp deps do
  [
    # Remove: {:esbuild, ...}
    # Remove: {:tailwind, ...}  # if present
    {:live_svelte, "~> 0.18.0-rc0"},
    {:phoenix_vite, "~> 0.4"},
    # ... rest of deps
  ]
end
2. Fetch deps:
mix deps.get

3. Add import LiveSvelte in html_helpers/0 inside lib/<app_name>_web.ex:
defp html_helpers do
  quote do
    # ...
    import LiveSvelte
    # ...
  end
end
4. Update config/config.exs — remove the esbuild and tailwind config blocks, add phoenix_vite + live_svelte SSR:
# Remove the entire: config :esbuild, ...
# Remove the entire: config :tailwind, ...  # if present

config :phoenix_vite, PhoenixVite.Npm,
  assets: [args: [], cd: Path.expand("..", __DIR__)],
  vite: [
    args: ~w(exec -- vite),
    cd: Path.expand("../assets", __DIR__),
    env: %{"MIX_BUILD_PATH" => Mix.Project.build_path()}
  ]

config :live_svelte, ssr: true
5. Update config/dev.exs — remove the esbuild and tailwind watchers, add the Vite dev server watcher and SSR config:
config :<app_name>, <AppName>Web.Endpoint,
  # ... existing config ...
  static_url: [host: "localhost", port: 5173],
  watchers: [
    # Remove: esbuild: {...}
    # Remove: tailwind: {...}  # if present
    vite: {PhoenixVite.Npm, :run, [:vite, ~w(dev)]}
  ]

config :live_svelte,
  ssr_module: LiveSvelte.SSR.ViteJS,
  vite_host: "http://localhost:5173"
6. Update config/prod.exs:
config :live_svelte,
  ssr_module: LiveSvelte.SSR.NodeJS,
  ssr: true
7. Update mix.exs aliases — replace esbuild/tailwind aliases with Vite:
# Remove: "assets.setup": ["esbuild.install --if-missing", ...]
# Remove: "assets.build": ["esbuild ...", "tailwind ...", ...]
"assets.setup": ["phoenix_vite.npm assets install"],
"assets.build": [
  "phoenix_vite.npm vite build --manifest --emptyOutDir true",
  "phoenix_vite.npm vite build --ssrManifest --emptyOutDir false --ssr js/server.js --outDir ../priv/svelte"
],
"assets.deploy": ["assets.build", "phx.digest"]
8. Create package.json in the project root (not in assets/). If your project uses Tailwind, add the Tailwind v4 npm packages:
{
  "type": "module",
  "dependencies": {
    "live_svelte": "file:./deps/live_svelte",
    "phoenix": "file:./deps/phoenix",
    "phoenix_html": "file:./deps/phoenix_html",
    "phoenix_live_view": "file:./deps/phoenix_live_view",
    "topbar": "^3.0.0"
  },
  "devDependencies": {
    "@sveltejs/vite-plugin-svelte": "^7.0.0",
    "phoenix_vite": "file:./deps/phoenix_vite",
    "svelte": "^5.0.0",
    "vite": "^8.0.0",
    "@tailwindcss/vite": "^4.1.0",
    "tailwindcss": "^4.1.0"
  }
}
Without Tailwind, omit the last two @tailwindcss/vite and tailwindcss entries.
9. Create assets/vite.config.mjs. If using Tailwind, import and add the tailwindcss() plugin:
import { defineConfig } from "vite"
import { svelte } from "@sveltejs/vite-plugin-svelte"
import liveSveltePlugin from "live_svelte/vitePlugin"
// With Tailwind: add this import
import tailwindcss from "@tailwindcss/vite"

export default defineConfig({
  server: {
    host: "127.0.0.1",
    port: 5173,
    strictPort: true,
    cors: { origin: "http://localhost:4000" },
  },
  optimizeDeps: {
    include: ["live_svelte", "phoenix", "phoenix_html", "phoenix_live_view"],
  },
  ssr: { noExternal: process.env.NODE_ENV === "production" ? true : undefined },
  build: {
    manifest: false,
    ssrManifest: false,
    rollupOptions: { input: ["js/app.js", "css/app.css"] },
    outDir: "../priv/static",
    emptyOutDir: true,
  },
  // Required for Phoenix 1.8+ colocated JS hooks
  resolve: {
    alias: {
      "phoenix-colocated": `${process.env.MIX_BUILD_PATH}/phoenix-colocated`,
    },
  },
  plugins: [
    tailwindcss(), // With Tailwind: include this; remove if not using Tailwind
    svelte({ compilerOptions: { css: "injected" } }),
    liveSveltePlugin({ entrypoint: "./js/server.js" }),
  ],
})
10. Create assets/js/server.js:
import { getRender } from "live_svelte"
import Components from "virtual:live-svelte-components"
export const render = getRender(Components)
11. Update assets/js/app.js:
	Change import topbar from "../vendor/topbar" → import topbar from "topbar"
	Add the LiveSvelte hooks to LiveSocket:

import {getHooks} from "live_svelte"
import Components from "virtual:live-svelte-components"

const liveSocket = new LiveSocket("/live", Socket, {
  // Merge into your existing hooks:
  hooks: {...colocatedHooks, ...getHooks(Components)},
  // ...
})
If your app doesn't use colocated hooks (older Phoenix), use hooks: {...getHooks(Components)}.
12. Update lib/<app_name>_web/components/layouts/root.html.heex — replace the static <link> and <script> asset tags with the Vite-aware component:
<PhoenixVite.Components.assets
  names={["js/app.js", "css/app.css"]}
  manifest={{:<app_name>, "priv/static/.vite/manifest.json"}}
  dev_server={PhoenixVite.Components.has_vite_watcher?(<AppName>Web.Endpoint)}
  to_url={fn p -> static_url(@conn, p) end}
/>
13. Update lib/<app_name>_web/endpoint.ex — add PhoenixVite.Plug:
defmodule <AppName>Web.Endpoint do
  use Phoenix.Endpoint, otp_app: :<app_name>
  import PhoenixVite.Plug

  plug :favicon, dev_server: {PhoenixVite.Components, :has_vite_watcher?, [__MODULE__]}

  # ... rest of endpoint
end
14. Update lib/<app_name>/application.ex — add NodeJS.Supervisor for production SSR. The conditional ensures it only starts when NodeJS SSR is configured (production):
def start(_type, _args) do
  node_js_children =
    if Application.get_env(:live_svelte, :ssr_module, nil) == LiveSvelte.SSR.NodeJS do
      [{NodeJS.Supervisor, [path: LiveSvelte.SSR.NodeJS.server_path(), pool_size: 4]}]
    else
      []
    end

  children = node_js_children ++ [
    # ... your existing children
  ]
  # ...
end
15. If assets/css/app.css does not exist, create it (Vite needs it as a build entry):
Without Tailwind:
/* Application CSS */
With Tailwind v4:
@import "tailwindcss";
@source "../svelte/**/*.svelte";
The @source "../svelte/**/*.svelte" glob tells Tailwind to scan Svelte components for class names. A bare directory path (@source "../svelte") does not include .svelte files by default — the explicit glob is required.
16. Install packages and build:
mix assets.setup
mix assets.build
mix phx.server

Visit http://localhost:4000/svelte_demo to confirm the demo Svelte component is working (added automatically by Igniter; for manual install, create a LiveView that renders <.svelte name="YourComponent" props={%{}} socket={@socket} />).
Usage
Svelte components need to go into the assets/svelte directory
Attributes:
	  name: Specify the Svelte component
	  props (Optional): Provide the props you want to use that should be reactive as a map to the props field
	  class (Optional): Provide class to set the class attribute on the root svelte element
	  ssr (Optional): Set ssr to false to disable server-side rendering

e.g. If your component is named assets/svelte/Example.svelte:
def render(assigns) do
  ~H"""
  <.svelte name="Example" props={%{number: @number}} socket={@socket} />
  """
end
If your component is in a directory, for example assets/svelte/some-directory/SomeComponent.svelte you need to include the directory in your name: some-directory/SomeComponent.
The Components Macro
There is also an Elixir macro which checks your assets/svelte folder for any Svelte components, and injects local function defs for those components into the calling module.
This allows for an alternative, more JSX-like authoring experience inside Liveviews.
e.g. in the below example, a Svelte component called Example is available to be called inside the Liveview template:
use LiveSvelte.Components

def render(assigns) do
  ~H"""
  <.Example number={@number} socket={@socket} />
  """
end
Examples
Examples can be found in the /examples and /example_project directories.
Most of the /example_project examples are visible in the YouTube demo video.
I recommend cloning live_svelte and running the example project in /example_project by running the following commands:
git clone https://github.com/woutdp/live_svelte.git
# set up and run the example project
cd live_svelte/example_project
mix setup
mix phx.server

The example project uses phoenix_vite: mix phx.server starts both Phoenix and the Vite dev server, so Svelte/CSS changes hot-reload. Server will be running on localhost:4000. If you want to change the port, edit example_project/config/dev.exs and change the http config.
If you have examples you want to add, feel free to create a PR, I'd be happy to add them.
Create a Svelte component
<script>
    // The number prop is reactive,
    // this means if the server assigns the number, it will update in the frontend
    // live contains all exported LiveView methods available to the frontend
   let {number = 1, live} = $props();

    function increase() {
        // This pushes the event over the websocket
        // The last parameter is optional. It's a callback for when the event is finished.
        // You could for example set a loading state until the event is finished if it takes a longer time.
        live.pushEvent("set_number", {number: number + 1}, () => {})

        // Note that we actually never set the number in the frontend!
        // We ONLY push the event to the server.
        // This is the E2E reactivity in action!
        // The number will automatically be updated through the LiveView websocket
    }

    function decrease() {
        live.pushEvent("set_number", {number: number - 1}, () => {})
    }
</script>

<p>The number is {number}</p>
<button onclick={increase}>+</button>
<button onclick={decrease}>-</button>
Note: that here we use the pushEvent function, but you could also use phx-click and phx-value-number if you wanted.
The following methods are available on live:
	  pushEvent
	  pushEventTo
	  handleEvent
	  removeHandleEvent
	  upload
	  uploadTo

These need to be run on the client, they can't be run in SSR. Either make sure they're called on an action (e.g. clicking a button) or wrap them with onMount.
More about this in the LiveView documentation on js-interop
Create a LiveView
# `/lib/app_web/live/live_svelte.ex`
defmodule AppWeb.SvelteLive do
  use AppWeb, :live_view

  def render(assigns) do
    ~H"""
    <.svelte name="Example" props={%{number: @number}} socket={@socket} />
    """
  end

  def handle_event("set_number", %{"number" => number}, socket) do
    {:noreply, assign(socket, :number, number)}
  end

  def mount(_params, _session, socket) do
    {:ok, assign(socket, :number, 5)}
  end
end
# `/lib/app_web/router.ex`
import Phoenix.LiveView.Router

scope "/", AppWeb do
  ...
  live "/svelte", SvelteLive
  ...
end
LiveSvelte As An Alternative LiveView DSL
Blogpost on the topic
We can go one step further and use LiveSvelte as an alternative to the standard LiveView DSL. This idea is inspired by Surface UI.
Take a look at the following example:
defmodule ExampleWeb.LiveSigil do
  use ExampleWeb, :live_view

  def render(assigns) do
    ~V"""
    <script>
      let {number = 5} = $props();
      let other = $state(1);
      let combined = $derived(other + number);
    </script>

    <p>This is number: {number}</p>
    <p>This is other: {other}</p>
    <p>This is other + number: {combined}</p>

    <button phx-click="increment">Increment</button>
    <button onclick={() => other += 1}>Increment</button>
    """
  end

  def mount(_params, _session, socket) do
    {:ok, assign(socket, :number, 1)}
  end

  def handle_event("increment", _value, socket) do
    {:noreply, assign(socket, :number, socket.assigns.number + 1)}
  end
end
Use the ~V sigil instead of ~H and your LiveView will be Svelte instead of an HEEx template.
Installation
	If it's not already imported inside html_helpers/0, add import LiveSvelte inside the live_view function in your project, this can be found in /lib/<app_name>_web.ex:

def live_view do
  quote do
    use Phoenix.LiveView,
      layout: {ExampleWeb.Layouts, :app}

    import LiveSvelte

    unquote(html_helpers())
  end
end
	Ignore build files in your .gitignore. The sigil will create Svelte files that are then picked up by Vite, these files don't need to be included in your git repo:

# Ignore automatically generated Svelte files by the ~V sigil
/assets/svelte/_build/
Neovim Treesitter Config
To enable syntax highlighting in Neovim with Treesitter, create the following file:
~/.config/nvim/after/queries/elixir/injections.scm
; extends

; Svelte
(sigil
  (sigil_name) @_sigil_name
  (quoted_content) @injection.content
 (#eq? @_sigil_name "V")
 (#set! injection.language "svelte"))
For Neovim Treesitter version below v0.9:
; extends

; Svelte
(sigil
  (sigil_name) @_sigil_name
  (quoted_content) @svelte
(#eq? @_sigil_name "V"))
Also make sure Svelte and Elixir is installed in Treesitter.
Options
Options can be passed in the mount by setting svelte_opts, check the following example:
def mount(_params, _session, socket) do
  {:ok, assign(socket, some_value: 1, svelte_opts: %{ssr: false, class: "example-class"})}
end
LiveView Live Navigation Events
Inside Svelte you can define Live Navigation links. These links navigate from one LiveView to the other without refreshing the page.
For example this can be useful when you have a Svelte store and you want this store state to remain during navigation. Example of Svelte store usage can be found in /examples/store.
push_navigate
<a href="/your-liveview-path" data-phx-link="redirect" data-phx-link-state="push">Redirect</a>
push_patch
<a href="/your-liveview-path" data-phx-link="patch" data-phx-link-state="push">Patch</a>
LiveView JavaScript Interoperability
LiveView allows for a bunch of interoperability which you can read more about here:
https://hexdocs.pm/phoenix_live_view/js-interop.html
Preprocessor
To use the preprocessor, install the desired preprocessor.
e.g. Typescript
cd assets && npm install --save-dev typescript
SSR (Server-Side Rendering)
If you're unfamiliar with SSR (Server-Side Rendering), it is a feature of Svelte to... render Svelte on the server. This means on first page load you get to see HTML instead of a blank page. Immediately after the first page load the page is 'hydrated', which is a fancy word for adding reactivity to your component. This happens in the background, you don't notice this step happening.
The way LiveSvelte updates itself through LiveView is by letting Svelte handle all the HTML edits. Usually LiveView would edit the HTML by passing messages through the websocket. In our case we only pass the data we provided in the props attribute to Svelte through the websocket. No HTML is being touched by LiveView, Svelte takes care of that.
Like mentioned, without SSR you'd see a brief flash of un-rendered content. Sometimes you can get away with not rendering Svelte on the server, for example when your Svelte component doesn't do any rendering on first page load and needs to be manually toggled for visibility by the user. Or when it is a component that has no visual component to it like tracking your mouse cursor and sending it back to the server.
In theses cases you can turn off SSR.
Important: Set NODE_ENV to production in production deployments
When deploying your application to production, you must set the NODE_ENV environment variable to production. If this is not done, your application may experience a memory leak and significantly reduced performance during SSR. For Docker deployments, you can add the following line to your production Dockerfile as an example:
ENV NODE_ENV production
Disabling SSR
SSR is enabled by default when you install LiveSvelte. If you don't want to use Server-Side Rendering for Svelte, you can disable it in the following ways:
Globally
If you don't want to use SSR on any component you can disable it globally.
There are 2 ways of doing this
	  Don't include the NodeJS supervisor in the application.ex file
or
	  Add ssr: false to the live_svelte config in your config.exs file like so:

config :live_svelte,
  ssr: false
Component
To disable SSR on a specific component, set the ssr property to false. Like so:
<.svelte name="Example" ssr={false} />
Auto-generated IDs and loops
When the same Svelte component is rendered multiple times (e.g. in a for loop),
LiveSvelte automatically generates unique, stable DOM IDs so that LiveView can
correctly reconcile hook elements across re-renders.
How it works (priority order):
	Explicit id — if you pass id="my-id", that value is used as-is.
	Explicit key — if you pass key={index}, the DOM id becomes ComponentName-<key>.
	Auto-detected identity from props — LiveSvelte inspects the props map for
common identity keys (:id, :key, :index, :idx and their string equivalents).
When found, the value is appended to the component name to form a deterministic ID.
	Counter fallback — when none of the above apply, a simple per-name counter
produces sequential IDs (Name, Name-1, Name-2, …). This works for
standalone components but is not reliable inside comprehensions.

For most loops you already pass an index or id in your props, so IDs are
generated automatically with no extra work:
<%= for {item, index} <- Enum.with_index(@list) do %>
  <%!-- index in props → auto-generates ids: "Card-0", "Card-1", … --%>
  <.svelte name="Card" props={%{index: index, color: @color}} />
<% end %>
If your props don't contain a natural identity key, use the key attribute:
<%= for {item, index} <- Enum.with_index(@list) do %>
  <.svelte name="Chart" key={index} props={%{data: item.data}} />
<% end %>
Props diffing (change tracking)
When props diffing is enabled, LiveSvelte sends only changed props to the client on updates, so unchanged props are not included in the payload and updates are minimal.
	  Config: config :live_svelte, enable_props_diff: true (default). Set to false to always send full props.
	  Per component: Use the diff attribute to opt out on a single component: <.svelte name="Example" props={@props} diff={false} />.

On the initial render or when the socket is disconnected, full props are always sent. When connected and diffing is on, only keys that changed (compared to the previous render) are sent, and the client merges them into existing state.
JSON Library
LiveSvelte uses Erlang/OTP 27's native :json module by default for JSON encoding.
This provides excellent performance without requiring external dependencies.
Note: LiveSvelte requires Elixir 1.17+ and OTP 27+ for the native JSON module.
Using Jason or Poison
If you prefer to use Jason, Poison, or another JSON library, configure it in your config.exs:
# config/config.exs
config :live_svelte, json_library: Jason
Add the dependency to your mix.exs:
# mix.exs
defp deps do
  [
    {:live_svelte, "~> 0.17"},
    {:jason, "~> 1.2"}  # or {:poison, "~> 5.0"}
  ]
end
The JSON library must implement encode!/1 that accepts any Elixir term and returns a JSON string.
Struct Encoding
The native JSON encoder automatically converts structs to maps before encoding. This means
you don't need @derive Jason.Encoder when using the default native JSON encoder.
If you're using Jason and need custom struct encoding behavior, see the
Structs and Ecto section for details on @derive Jason.Encoder.
LiveSvelte.Encoder protocol
All props pass through the LiveSvelte.Encoder protocol before JSON encoding. You can control which struct fields are sent to Svelte with @derive:
defmodule User do
  @derive {LiveSvelte.Encoder, except: [:password]}
  defstruct [:name, :email, :password]
end
	@derive LiveSvelte.Encoder — encode all fields except __struct__
	@derive {LiveSvelte.Encoder, only: [:name, :email]} — encode only listed keys
	@derive {LiveSvelte.Encoder, except: [:password]} — encode all except listed keys

Phoenix.HTML.Form, Ecto.Changeset, and Phoenix LiveView upload structs have built-in encoders. Date/Time types are encoded as ISO8601 strings.
For efficient updates when only some props change, use the built-in props diffing (see Configuration) and JSON Patch support; the former live_json integration has been removed.
Structs and Ecto
LiveSvelte serializes data passed in props to JSON so it can be handled by JavaScript.
With native JSON (default): Structs are automatically converted to maps. No additional configuration needed.
With Jason: Jason doesn't know how to handle structs by default, so you need to define it yourself using @derive.
Structs (Jason only)
If you're using Jason and have a struct like this:
defmodule User do
  defstruct name: "John", age: 27, address: "Main St"
end
You must define @derive
defmodule User do
  @derive Jason.Encoder
  defstruct name: "John", age: 27, address: "Main St"
end
Be careful though, as you might accidentally leak certain fields you don't want the client to access, you can include which fields to serialize:
defmodule User do
  @derive {Jason.Encoder, only: [:name, :age]}
  defstruct name: "John", age: 27, address: "Main St"
end
Ecto (Jason only)
When using Jason with Ecto schemas, it's important to also omit the __meta__ field as it's not serializable.
Check out the following example:
defmodule Example.Planets.Planet do
  use Ecto.Schema
  import Ecto.Changeset
  @derive {Jason.Encoder, except: [:__meta__]}

  schema "planets" do
    field :diameter, :integer
    field :mass, :integer
    field :name, :string

    timestamps()
  end

  ...
end
Documentation
More documentation on the topic:
	  HexDocs
	  GitHub

Slots
You can slot Elixir inside a LiveSvelte component like so:
<.svelte name="Example">
  <p>Slot content</p>
</.svelte>
And in the Svelte file it will look like this:
<script>
    let {children}: = $props()
</script>

<i>Opening</i>
  {@render children?.()}
<i>Closing</i>
Named slots also work:
<.svelte name="Example">
  Main content
  <:subtitle>
    <p>Slot content</p>
  </:subtitle>
</.svelte>
<script>
    let {children, subtitle}: = $props()
</script>

<i>Opening</i>
  {@render children()}
  <h2>{@render subtitle()}</h2>
<i>Closing</i>
This works because of the Snippet API provided by Svelte. Be careful though, it's a new feature that might not be working 100% of the time, I'd love to see what limitations you hit with it. One limitation is that you can't slot other Svelte components.
ℹ️ Note: Slotted Content is wrapped with a div
LiveSvelte wraps all slotted content in a <div> element.
This is a limitation to how createRawSnippet works in Svelte, which is used under the hood in LiveSvelte to make this feature work.

Showing fallback content with :loading
When SSR is disabled, a full‑page refresh briefly shows a blank content before Svelte finishes loading.
Use the :loading slot to render a placeholder during that gap:
<.svelte name="Example" ssr={false}>
  <:loading>
    <p>Until your LiveSvelte component renders client-side, this will be displayed</p>
  </:loading>
</.svelte>
Caveats
"Secret State"
With LiveView, it's easy to keep things secret. Let's say you have a conditional that only renders when something is true, in LiveView there's no way to know what that conditional will show until it is shown, that's because the HTML is sent over the wire.
With LiveSvelte, we're dealing with JSON being sent to Svelte, which in turn takes that JSON data and conditionally renders something, even if we don't set the conditional to true, the Svelte code will contain code on what to show when the conditional turns true.
In a lot of scenarios this is not an issue, but it can be and is something you should be aware of.
LiveSvelte Development
Local Setup
Example Project
You can use /example_project as a way to test live_svelte locally.
Custom Project
You can also use your own project.
Clone live_svelte to the parent directory of the project you want to test it in.
Inside mix.exs
{:live_svelte, path: "../live_svelte"},
Inside assets/package.json
"live_svelte": "file:../../live_svelte",
Development Workflow
LiveSvelte ships TypeScript source directly — there are no pre-built distribution files. Consumers compile the library source through their own Vite pipeline via the live_svelte package alias.
When working on the library source in assets/js/live_svelte/, rebuild the example project so Vite picks up the changes:
# From example_project/ — rebuild after library source changes:
mix assets.build && mix compile

The example project uses phoenix_vite, so a single mix phx.server starts both Phoenix and the Vite dev server; Svelte and library changes hot-reload with no second terminal.
Type checking: The LiveSvelte client library is written in TypeScript with a type-safe public API (no any in exported types). Consumers get type hints via the package types entry. From the library repo, run npm run typecheck in live_svelte/assets to run tsc --noEmit.
Releasing
For hex.pm releases of LiveSvelte itself, use the easy_publish-powered tasks:
mix release.patch    # Patch version bump
mix release.minor    # Minor version bump
mix release.major    # Major version bump

These commands will bump the version, update the changelog, commit, tag, push, and publish to Hex in one step.
Deployment
Deploying a LiveSvelte app is the same as deploying a regular Phoenix app, except that you will need to ensure that nodejs (version 19 or later) is installed in your production environment.
The below guide shows how to deploy a LiveSvelte app to Fly.io, but similar steps can be taken to deploy to other hosting providers.
You can find more information on how to deploy a Phoenix app here.
Note: For best performance and to avoid memory leaks, always set the NODE_ENV environment variable to production in your production environment.

Deploying on Fly.io
The following steps are needed to deploy to Fly.io. This guide assumes that you'll be using Fly Postgres as your database. Further guidance on how to deploy to Fly.io can be found here.
	Generate a Dockerfile:

mix phx.gen.release --docker

	Modify the generated Dockerfile to install curl, which is used to install nodejs (version 19 or greater), and also add a step to install our npm dependencies:

# ./Dockerfile

...

# install build dependencies
- RUN apt-get update -y && apt-get install -y build-essential git \
+ RUN apt-get update -y && apt-get install -y build-essential git curl \
    && apt-get clean && rm -f /var/lib/apt/lists/*_*

+ # install nodejs for build stage
+ RUN curl -fsSL https://deb.nodesource.com/setup_19.x | bash - && apt-get install -y nodejs

...

COPY assets assets

+ # install all npm packages in assets directory
+ WORKDIR /app/assets
+ RUN npm install

+ # change back to build dir
+ WORKDIR /app

...

# start a new build stage so that the final image will only contain
# the compiled release and other runtime necessities
FROM ${RUNNER_IMAGE}

RUN apt-get update -y && \
-  apt-get install -y libstdc++6 openssl libncurses5 locales ca-certificates \
+  apt-get install -y libstdc++6 openssl libncurses5 locales ca-certificates curl \
   && apt-get clean && rm -f /var/lib/apt/lists/*_*

+ # install nodejs for production environment
+ RUN curl -fsSL https://deb.nodesource.com/setup_19.x | bash - && apt-get install -y nodejs

...
Note: nodejs is installed BOTH in the build stage and in the final image. This is because we need nodejs to install our npm dependencies and also need it when running our app.
	Launch your app with the Fly.io CLI:

fly launch

	When prompted to tweak settings, choose y:

? Do you want to tweak these settings before proceeding? (y/N) y

This will launch a new window where you can tweak your launch settings. In the database section, choose Fly Postgres and enter a name for your database. You may also want to change your database to the development configuration to avoid extra costs. You can leave the rest of the settings as-is unless you want to change them.
Deployment will continue once you hit confirm.
	Once the deployment completes, run the following command to see your deployed app!

fly apps open

Svelte 4 -> Svelte 5 migration guide
Since version 0.15.0, LiveSvelte supports Svelte 5. If you want to use Svelte 4, use version 0.14.0. Note that Svelte 5 is backwards compatible with Svelte 4 for the most part, so even if you're using Svelte 4 syntax, with the latest version it should still work, and so there should be few reasons why to stay on version 0.14.0.
To migrate your project from 0.14.0 to 0.15.0 you need to follow the following 3 steps:
	Update mix.exs and run mix deps.get

# `mix.exs`
{:live_svelte, "0.15.0"}`
	Update to the latest Svelte 5 in your package.json

  // package.json
 "svelte": "^5",
	Update your Vite configuration to use @sveltejs/vite-plugin-svelte with Svelte 5.
Refer to the installation guide for the current Vite setup.

Credits
	  Ryan Cooke - E2E Reactivity using Svelte with Phoenix LiveView
	  Svonix
	  Sveltex

Alternatives for other frontend frameworks
	  Vue: LiveVue
	  React: LiveReact

LiveSvelte Projects
	  ash-svelte-flowbite
	  Local-First Todo App
	  Beacon LiveAdmin
	  TV Labs

Using LiveSvelte in a public project? Let me know and I'll add it to this list!

Renders a Svelte component on the server.
Attributes
	props (:map) - Props to pass to the Svelte component. Defaults to %{}. Examples include %{foo: "bar"}, %{foo: "bar", baz: 1}, and %{list: [], baz: 1, qux: %{a: 1, b: 2}}.
	name (:string) (required) - Name of the Svelte component. Examples include "YourComponent", and "directory/Example".
	id (:string) - Optional stable DOM id override. Auto-generated from the component name and props by default. Only needed when auto-detection is insufficient (e.g. two loops with the same component name). Defaults to nil.
	key (:any) - Identity key for stable DOM IDs in loops. When set, the DOM id becomes name-key. When not set, LiveSvelte auto-detects identity from props (id, key, index, idx keys). Defaults to nil.
	class (:string) - Class to apply to the Svelte component. Defaults to nil. Examples include "my-class", and "my-class another-class".
	ssr (:boolean) - Whether to render the component via NodeJS on the server. Defaults to true. Examples include true, and false.
	socket (:map) - LiveView socket, only needed when ssr: true. Defaults to nil.
	diff (:boolean) - When true (and config enable_props_diff is true), only changed props are sent on update. Set to false to always send full props. Defaults to true.

Slots
	inner_block - Inner block of the Svelte component.
	loading - LiveView rendered markup to show while the component is loading client-side.

